1、熟練氧化、離子注入與擴(kuò)散工藝，使用Silvaco軟件進(jìn)行模擬

2、掌握nmos工藝流程。

3、學(xué)會(huì)用Silvaco軟件提取MOS晶體管的各種參數(shù)

4、掌握MOS晶體管器件模擬

二．實(shí)驗(yàn)要求

1.用Anthena構(gòu)建一個(gè)NMOS管，要求溝道長(zhǎng)度不小于0.8微米，閾值電壓在-0.5v 至 1V之間，要說(shuō)明在工藝中如何調(diào)整閾值電壓并在模擬結(jié)果中有所體現(xiàn)。

2.工藝模擬過(guò)程要求提取S/D結(jié)結(jié)深、閾值電壓、溝道表面摻雜濃度、S/D區(qū)薄層電阻等參數(shù)。

3.進(jìn)行器件模擬，要求得到NMOS輸出特性曲線族以及特定漏極電壓下的轉(zhuǎn)移特性曲線，并從中提取MOS管的閾值電壓和β值。

4.分析各關(guān)鍵工藝步驟對(duì)器件性能的影響。

三．實(shí)驗(yàn)步驟：

1、啟動(dòng)silvaco軟件。

2、創(chuàng)建一個(gè)網(wǎng)格并定義襯底的參數(shù)。

3、由于本實(shí)驗(yàn)運(yùn)用了cmos工藝，所以先在襯底上做一個(gè)p阱，嚴(yán)格定義p阱的濃度，注入能量，以及阱區(qū)的推進(jìn)。

4、生長(zhǎng)柵氧化層，嚴(yán)格控制各參數(shù)。

diffus time=10 temp=950 dryo2 press=1.00 hcl.pc=3

5、淀積多晶硅，其厚度為0.2um。

6、刻蝕掉x=0.35左面的多晶硅，然后低劑量注入磷離子，形成輕摻雜層，劑量為3e13，能量為20kev。

7、淀積氧化層，然后再進(jìn)行刻蝕，以進(jìn)行下一步的源漏區(qū)注入。

8、進(jìn)行源漏砷離子的注入，劑量為4e15，能量為40kev。

9、淀積鋁，形成S/D金屬接觸。

10、進(jìn)行向右鏡像操作，形成完整的nmos結(jié)構(gòu)并定義電極。

11、抽取源漏結(jié)深，閾值電壓，n+區(qū)薄層電阻，溝道表面摻雜濃度，輕摻雜源漏區(qū)的薄層電阻等參數(shù)。

12、描述輸出特性曲線并繪出。

13、描述轉(zhuǎn)移特性曲線并繪出，同時(shí)從中提取MOS管的閾值電壓和β值。

四、實(shí)驗(yàn)結(jié)果及分析

1、工藝圖

由圖可見，此NMOS溝道長(zhǎng)度不小于0.8微米，符合要求。

2、工藝過(guò)程：

（1）定義矩形網(wǎng)格：

#定義X網(wǎng)格

line x loc=0 spac=0.1

line x loc=0.2 spac=0.006

line x loc=0.6 spac=0.006

#定義Y網(wǎng)格

line y loc=0.00 spac=0.002

line y loc=0.2 spac=0.005

line y loc=0.5 spac=0.05

line y loc=0.8 spac=0.15

（2）定義初始硅并氧化：100 晶向，作為P 型襯底，用硼摻雜，摻雜濃度為1e14，之后制作柵氧化層：把硅片放在950攝氏度，干氧，一個(gè)大氣壓下?lián)铰龋然瘹洌┭趸?0分鐘，結(jié)果如下：

不同的氧化方式或氧化時(shí)間等參數(shù)的不同會(huì)使其氧化層厚度不同，并且不同的氧化方式（例如濕氧氧化與干氧氧化作對(duì)比）、不同的氧化溫度和時(shí)間等因素對(duì)襯底雜質(zhì)再分布也會(huì)有不同程度影響，綜合比較后，我選擇了干氧氧化柵氧化層。

（3）調(diào)整閾值電壓，離子注入，注入硼離子，劑量為2e12，能量為10KeV：

此摻雜包括后續(xù)的摻雜過(guò)程均可以使用擴(kuò)散或離子注入實(shí)現(xiàn)。擴(kuò)散是利用雜質(zhì)離子的自由擴(kuò)散實(shí)現(xiàn)，它同時(shí)存在縱向和橫向的擴(kuò)散，擴(kuò)散的時(shí)間越長(zhǎng)，摻雜的深度和寬度都增加，橫向效應(yīng)明顯，但在小尺寸工藝中，要求有必要的參雜深度，同時(shí)希望很小的橫向間距，這時(shí)候擴(kuò)散就很難做到。所以我在這里選擇了離子注入，它的摻雜是精確控制的，注入離子的種類、注入深度都可以精確控制，同時(shí)幾乎沒(méi)有橫向擴(kuò)散，但是容易產(chǎn)生缺陷，需要退火。

（4）淀積Poly層后進(jìn)行柵刻蝕:刻蝕掉x=0.35左面的多晶硅，結(jié)果如下：

（5）濕氧氧化后進(jìn)行輕摻雜，輕摻雜使用離子注入，注入磷離子，劑量為3e13，能量為20KeV，之后沉積氧化層再進(jìn)行干刻蝕，以進(jìn)行下一步的源漏區(qū)注入 ，其結(jié)果如下：

（6）進(jìn)行源漏砷離子的注入，重?fù)诫s，劑量為4e15，能量為40KeV，摻雜完成后進(jìn)行快速退火，結(jié)果如下：

上述摻雜工藝選擇離子注入的原因是為了減小橫向效應(yīng)，防止源漏擴(kuò)散使溝道長(zhǎng)度變短。

（7）下面處理漏源極，先刻蝕掉x=0.1以左的氧化層 ，再刻蝕掉一個(gè)矩形,把柵極多晶硅上面的氧化層刻蝕掉，以便于之后與金屬接觸制作電極。我蝕刻掉了（0.357,-0.15）->(0.6,-0.15)->(0.6,-0.3)->(0.357,-0.3)區(qū)域內(nèi)的氧化層，結(jié)果如下：

（8）在表面淀積鋁之后，刻蝕掉一個(gè)矩形區(qū)域的鋁，留下金屬電極。我蝕刻掉了（0.35,0.1）->(0.1,0.1)->(0.1,-0.4)->(0.35,0.4)區(qū)域內(nèi)的鋁，結(jié)果如下：

（9）進(jìn)行鏡像和電極定義，鏡像對(duì)稱并保存鏡像結(jié)構(gòu)后，完整的NMOS如下：

至此，完整的NMOS設(shè)計(jì)工藝過(guò)程結(jié)束。

3、器件仿真結(jié)果及參數(shù)特性分析：

（1）結(jié)深：

結(jié)深測(cè)量語(yǔ)句：extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

測(cè)量結(jié)果：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=0.882642 um from top of first Silicon layer X.val=0.1

（2）測(cè)量溝道閾值電壓

溝道閾值電壓測(cè)量語(yǔ)句：

extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

測(cè)量結(jié)果：

EXTRACT> extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

n1dvt=0.953742 V X.val=0.49

（3）溝道表面摻雜濃度

溝道表面摻雜濃度測(cè)量語(yǔ)句：

extract name="chan surf conc" surf.conc impurity="Net Doping" \

material="Silicon" mat.occno=1 x.val=0.45

測(cè)量結(jié)果：

EXTRACT> extract name="chan surf conc" surf.conc impurity="Net Doping"

chan surf conc=8.22657e+020 atoms/cm3

（4）獲取S/D區(qū)薄層電阻

獲取語(yǔ)句：

extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

獲取結(jié)果：

EXTRACT> #extract the N++ regions sheet resistance

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=40.5223 ohm/square X.val=0.05

（5）NMOS輸出特性曲線

上圖為該器件仿真 Id-VDS曲線（輸出特性曲線）的結(jié)果，由圖可知：

1、由理論知識(shí)得，當(dāng)柵極電壓小于NMOS閾值電壓時(shí)，沒(méi)有導(dǎo)電溝道形成，無(wú)論VDS取值如何，均不會(huì)有漏極電流：圖中紅色輸出曲線是柵壓為0.5V時(shí)（NMOS截止）的輸出曲線。

2、當(dāng)柵極電壓大于NMOS閾值電壓時(shí)，在柵極下方的襯底會(huì)出現(xiàn)反型層，從而形成導(dǎo)電溝道，此時(shí)在漏源區(qū)加上電壓VDS，就會(huì)產(chǎn)生漏極電流。

3、當(dāng)VDS較小時(shí)，漏極電流隨VDS呈線性增長(zhǎng)，此時(shí) MOSFET 工作在線性區(qū)。

4、繼續(xù)增大VDS，一定程度后導(dǎo)電溝道會(huì)被夾斷，此后Id不再隨VDS的增大而變化，Id只與柵極電壓VGS有關(guān)，此時(shí)MOSFET 工作在飽和區(qū)。（上方除紅色曲線外三條輸出曲線分別是柵極電壓為1.1V、2.2V、3.3V 時(shí)的輸出特性曲線，說(shuō)明 NMOS 的輸出特性曲線隨柵極電壓的不同而變化。）

由仿真結(jié)果可知，NMOS輸出特性與理論分析相符。

（6）NMOS轉(zhuǎn)移特性曲線

上圖為漏極電壓VDS恒定時(shí)的 Id-VGS 曲線（轉(zhuǎn)移特性曲線），由曲線可以看出：

1、當(dāng)VDS一定時(shí)，柵壓很小的時(shí)候不存在導(dǎo)電溝道，NMOS截止。

2、隨著柵極電壓VGS的增大，P型襯底將出現(xiàn)反型層，當(dāng)VGS大于NMOS閾值電壓時(shí)，導(dǎo)電溝道出現(xiàn)且寬度變寬，載流子濃度隨VGS的增大而增加，VDS呈線性增長(zhǎng)。

由仿真結(jié)果可以看出， NMOS轉(zhuǎn)移特性與理論分析相符。

（7）提取MOS管的閾值電壓

EXTRACT>extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),

abs(i."drain"))))- abs(ave(v."drain"))/2.0)

nvt=0.751552

可見此NMOS閾值電壓在-0.5v 至 1V之間，符合要求。

（8）提取參數(shù)

1、nxj=0.882642 um 2、n1dvt=0.953742 V

3、chan surf conc=8.22657e+020 atoms/cm3 4、n++ sheet rho=40.5223 ohm/square

5、nvt=0.751552 6、nbeta=0.000173251

4、工藝對(duì)器件性能及指標(biāo)的影響分析：

（1）柵氧化層氧化方式對(duì)器件性能及指標(biāo)的影響：參考標(biāo)準(zhǔn)如上述工藝，使用硅100 晶向作為P 型襯底，用硼摻雜（摻雜濃度為1e14）后，之后制作柵氧化層：把硅片放在950攝氏度，干氧，一個(gè)大氣壓下?lián)铰龋?%氯化氫）氧化10分鐘，氧化層和襯底摻雜濃度的結(jié)果如下：

上述干氧過(guò)程對(duì)柵氧化層厚度提取結(jié)果如下：

EXTRACT> extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

gateox=122.546 angstroms (0.0122546 um) X.val=0.3

在上述干氧過(guò)程基礎(chǔ)上后續(xù)工藝完成后，整個(gè)NMOS輸出特性結(jié)果如下：

接下來(lái)建立濕氧氧化對(duì)照組：用控制變量法分析干氧氧化與濕氧氧化對(duì)柵氧化層指標(biāo)的影響：把硅片放在950攝氏度，濕氧，一個(gè)大氣壓下?lián)铰龋?%氯化氫）氧化10分鐘，氧化層和襯底摻雜濃度的變化結(jié)果如下：

上述濕氧過(guò)程對(duì)柵氧化層厚度提取結(jié)果如下：

EXTRACT> extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

gateox=604.751 angstroms (0.0604751 um) X.val=0.3

可見若在其他參數(shù)不變的情況下改變氧化方式為濕氧氧化，其氧化層厚度將增加約6倍，并且濕氧氧化對(duì)襯底雜質(zhì)再分布有較大影響。

若在此濕氧氧化工藝的基礎(chǔ)上繼續(xù)進(jìn)行后續(xù)工序，會(huì)影響NMOS閾值電壓，從而影響其轉(zhuǎn)移特性曲線，其轉(zhuǎn)移特性曲線變化結(jié)果如下：

此NMOS閾值電壓提取結(jié)果如下：

EXTRACT> extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),

abs(i."drain"))))- abs(ave(v."drain"))/2.0)

nvt=-0.0316666

可見其閾值電壓為-0.0316666V，由此可見在濕氧氧化基礎(chǔ)上進(jìn)行后續(xù)工藝，會(huì)使得此NMOS由增強(qiáng)型NMOS管向耗盡型NMOS管變化，改變了其轉(zhuǎn)移特性。

（2）源漏區(qū)離子注入摻雜參數(shù)對(duì)器件性能及指標(biāo)的影響：參考標(biāo)準(zhǔn)如上述工藝，在進(jìn)行源漏砷離子的注入時(shí)，劑量為4e15，能量為40KeV，其離子注入工藝結(jié)束后雜質(zhì)分布結(jié)果如下：

在上述參數(shù)離子注入過(guò)程基礎(chǔ)上，后續(xù)工藝完成后整個(gè)NMOS對(duì)照組結(jié)深測(cè)量結(jié)果如下：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=0.882642 um from top of first Silicon layer X.val=0.1

對(duì)照組源漏區(qū)薄層電阻獲取結(jié)果：

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=40.5223 ohm/square X.val=0.05

接下來(lái)建立高能量摻雜的對(duì)照組，用控制變量法分析高能量離子注入對(duì)NMOS性能指標(biāo)的影響：在進(jìn)行源漏砷離子的注入時(shí)，劑量為4e15，能量為80KeV（為標(biāo)準(zhǔn)對(duì)照組的兩倍），其離子注入工藝結(jié)束后雜質(zhì)分布結(jié)果如下：

可見源（漏）重?fù)诫s區(qū)域相較于對(duì)照組深度明顯加深，其源漏結(jié)深測(cè)量結(jié)果：

EXTRACT> extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

nxj=1.69514 um from top of first Silicon layer X.val=0.1

其源漏區(qū)薄層電阻獲取結(jié)果：

EXTRACT> extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

n++ sheet rho=26.0693 ohm/square X.val=0.05

可見若在其他參數(shù)不變的情況下，進(jìn)行源漏砷離子的注入時(shí)，劑量為4e15，能量為80KeV（為標(biāo)準(zhǔn)對(duì)照組的兩倍），則NMOS管源漏結(jié)深將增大約2倍，并且其源漏區(qū)薄層電阻將減小為原來(lái)的約1/2。

附錄

實(shí)驗(yàn)程序

go athena

#定義X網(wǎng)格

line x loc=0 spac=0.1

line x loc=0.2 spac=0.006

line x loc=0.65 spac=0.006

#定義Y網(wǎng)格

line y loc=0.00 spac=0.002

line y loc=0.2 spac=0.005

line y loc=0.5 spac=0.05

line y loc=1.0 spac=0.15

#定義初始硅：100 晶向，作為P 型襯底，用硼摻雜，摻雜濃度為1e14

init silicon c.boron=1e14 orientation=100 space.mul=2 two.d

#制作柵氧化層：把硅片放在950攝氏度，干氧，一個(gè)大氣壓下?lián)铰龋然瘹洌┭趸?0分鐘

diffus time=10 temp=950 dryo2 press=1.00 hcl.pc=3

#抽取柵氧化層厚度

extract name="gateox" thickness oxide mat.occno=1 x.val=0.3

#調(diào)整閾值電壓，離子注入，注入硼離子

implant boron dose=2e12 energy=10 pearson

#淀積Poly層

depo poly thick=0.25 divi=10

#柵刻蝕:刻蝕掉x=0.35左面的多晶硅

etch poly left p1.x=0.35

#濕氧氧化為輕摻雜做準(zhǔn)備

diffuse time=3 temp=900 weto2

#輕摻雜離子注入，注入磷離子，形成輕摻雜層，劑量為3e13，能量為20kev

implant phosphor dose=3e13 energy=20 tilt=0 rotation=0

#沉積氧化層再進(jìn)行干刻蝕，以進(jìn)行下一步的源漏區(qū)注入

depo oxide thick=0.120 divisions=8

etch oxide dry thick=0.120

#進(jìn)行源漏砷離子的注入，劑量為4e15，能量為40kev

implant arsenic dose=4.0e15 energy=40 tilt=0 rotation=0

#快速退火

method fermi

diffus time=1 temp=900 nitro press=1.00

#下面處理漏源極

#刻蝕掉x=0.1以左的氧化層

etch oxide left p1.x=0.1

#刻蝕掉一個(gè)矩形,把柵極多晶硅上面的氧化層刻蝕掉，我寫的下面四句蝕刻掉了（0.357,-0.15）->(0.6,-0.15)->(0.6,-0.3)->(0.357,-0.3)區(qū)域內(nèi)的氧化層

etch oxide start x=0.357 y=-0.15

etch cont x=0.65 y=-0.15

etch cont x=0.65 y=-0.3

etch done x=0.357 y=-0.3

#沉積鋁

deposit alumin thick=0.1 div=20

#刻蝕掉一個(gè)矩形區(qū)域的鋁，我寫的下面四句蝕刻掉了（0.35,0.1）->(0.1,0.1)->(0.1,-0.4)->(0.35,0.4)區(qū)域內(nèi)的鋁

etch alumin start x=0.35 y=0.1

etch cont x=0.1 y=0.1

etch cont x=0.1 y=-0.4

etch done x=0.35 y=-0.4

#接下來(lái)進(jìn)行結(jié)果分析的提取，查看器件特性

#Extract design parameters

#extract final S/D Xj

extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

#extract the N++ regions sheet resistance

extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

#extract the sheet rho under the spacer,of the LDD region

extract name="ldd sheet rho" sheet.res material="Silicon"

mat.occno=1 x.val=0.3 region.occno=1

#extract the surface conc under the channel.

extract name="chan surf conc" surf.conc impurity="Net Doping"

material="Silicon" mat.occno=1 x.val=0.45

#extract a curve of conductance versus bias.

extract start material="Polysilicon" mat.occno=1

bias=0.0 bias.step=0.2 bias.stop=2 x.val=0.45

extract done name="sheet cond v bias"

curve(bias,1dn.conduct material="Silicon" mat.occno=1 region.occno=1)

outfile="extract.dat"

#extract the long chan Vt

extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49

#接下來(lái)進(jìn)行鏡像和電極定義

#鏡像對(duì)稱

structure mirror right

#保存鏡像結(jié)構(gòu)，完整的nMOS

structure outfile=mirror.str

electrode name=gate x=0.5 y=-0.2

electrode name=source x=0.05 y=0

electrode name=drain x=1.30 y=0

electrode name=substrate backside

#工藝仿真器件制作完成，保存到我的LiTianhao-NMOS1_athena.str文件中

structure outfile=LiTianhao-NMOS1_athena.str

tonyplot LiTianhao-NMOS1_athena.str

#接下來(lái)進(jìn)行器件物理特性分析，先求柵壓為1.1V,2.2V,3.3V時(shí)，漏電流與漏電壓的關(guān)系，即進(jìn)行CVT分析

go atlas

# 定義柵極功能，N型接觸

contact name=gate n.poly

# 定義柵氧化層正電荷為3e10

interface qf=3e10

# 使用CVT模型分析 MOS

models cvt srh print numcarr=2

# 設(shè)置柵極偏置，同時(shí)設(shè)置Vds=0V

solve init

solve vgate=0.5 outf=solve_tmp0_LiTianhao

solve vgate=1.1 outf=solve_tmp1_LiTianhao

solve vgate=2.2 outf=solve_tmp2_LiTianhao

solve vgate=3.3 outf=solve_tmp3_LiTianhao

#加載文件和步進(jìn)Vd

load infile=solve_tmp0_LiTianhao

log outf=LiTianhao_MOSLEX_0.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

load infile=solve_tmp1_LiTianhao

log outf=LiTianhao_MOSLEX_1.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

load infile=solve_tmp2_LiTianhao

log outf=LiTianhao_MOSLEX_2.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

load infile=solve_tmp3_LiTianhao

log outf=LiTianhao_MOSLEX_3.log

solve name=drain vdrain=0 vfinal=3.3 vstep=0.3

# 提取最大漏極電流和β值（斜率）

extract name="nidsmax" max(i."drain")

extract name="sat_slope" slope(minslope(curve(v."drain",i."drain")))

tonyplot -overlay -st LiTianhao_MOSLEX_0.log LiTianhao_MOSLEX_1.log LiTianhao_MOSLEX_2.log LiTianhao_MOSLEX_3.log

#接下來(lái)進(jìn)行Vt 測(cè)試：返回 Vt、Beta 和 θ

go atlas

#建立材料模型

models cvt srh print

contact name=gate n.poly

interface qf=3e10

method gummel newton

solve init

# 漏極給偏置電壓

solve vdrain=0.1

# 柵壓步進(jìn)

log outf=LiTianhao-Vt.log master

solve vgate=0 vstep=0.25 vfinal=3.0 name=gate

save outf=LiTianhao-Vt.str

tonyplot LiTianhao-Vt.log

#提取器件參數(shù)

extract name="nvt"(xintercept(maxslope(curve(abs(v."gate"),abs(i."drain"))))- abs(ave(v."drain"))/2.0)

extract name="nbeta" slope(maxslope(curve(abs(v."gate"),abs(i."drain"))))* (1.0/abs(ave(v."drain")))

extract name="nsubvt" 1.0/slope(maxslope(curve(abs(v."gate"),log10(abs(i."drain")))))

quit

第二部分

使用Silvaco構(gòu)建PNP、NPN雙極型晶體管并提取各項(xiàng)工藝及器件參數(shù)

選做題目一：使用SILVACO軟件設(shè)計(jì)一個(gè)PNP管，進(jìn)行相應(yīng)的工藝模擬與器件模擬，要求輸出Gummel曲線及IC——VCE特性曲線，并調(diào)整相關(guān)參數(shù)，觀察并分析各關(guān)鍵工藝步驟對(duì)晶體管性能的影響。

一、用工藝軟件ATHENA制作的PNP基本結(jié)構(gòu)：

二、PNP型三極管Gummel曲線：

三、PNP型三極管共射極輸出特性曲線：

四、特性分析：

由圖可知，PNP型三極管基極導(dǎo)通電壓Vbe約為-0.1V。三極管工作在放大狀態(tài)時(shí)Vbe約為-0.1V到-0.5V之間。同時(shí)從輸出特性曲線可知，當(dāng)管子飽和時(shí)，飽和管壓降較小,Vces 約為-0.6V。它與NPN 型硅三極管相比,不僅電壓、電流方向不同，而且導(dǎo)通電壓數(shù)值較小。利用這些特點(diǎn)，可以很容易地在電路中區(qū)分出PNP型三極管。

五、工藝對(duì)器件性能及指標(biāo)的影響分析：

（1）是否進(jìn)行退火對(duì)器件性能及指標(biāo)的影響：參考標(biāo)準(zhǔn)：在工藝過(guò)程中進(jìn)行基區(qū)退火，發(fā)射區(qū)退火，接觸區(qū)退火，在退火的基礎(chǔ)上完成后續(xù)工藝后，整個(gè)PNP雙極型晶體管的雜質(zhì)濃度分布情況如下：

參照組Gummel曲線結(jié)果如下：

參照組共射極輸出特性結(jié)果如下：

接下來(lái)建立全程不進(jìn)行退火處理的對(duì)照組：用控制變量法分析全程不做任何退火處理的PNP雙極型晶體管特性，其雜質(zhì)濃度分布情況的變化結(jié)果如下：

上述對(duì)照組全程不做任何退火處理的PNP雙極型晶體管Gummel曲線結(jié)果如下：

PNP共射極輸出特性結(jié)果如下：

由結(jié)果可見，由于往半導(dǎo)體中注入雜質(zhì)離子時(shí)，高能量的入射離子會(huì)與半導(dǎo)體晶格上的原子碰撞，使一些晶格原子發(fā)生位移，結(jié)果造成大量的空位，會(huì)使得注入?yún)^(qū)中的原子排列混亂或者變成為非晶區(qū)。而在其他參數(shù)不變的情況下，若不選擇退火處理，將會(huì)使PNP雙極型晶體管各結(jié)處半導(dǎo)體無(wú)法恢復(fù)晶體結(jié)構(gòu)，也無(wú)法消除缺陷，會(huì)使得其放大區(qū)變窄，放大區(qū)輸出特性變差，管子很容易進(jìn)入飽和區(qū)。

六、附錄：實(shí)驗(yàn)程序與詳細(xì)注釋：

go athena

#定義網(wǎng)格

line x loc=0.0 spacing=0.03

line x loc=0.2 spacing=0.02

line x loc=0.24 spacing=0.01

line x loc=0.3 spacing=0.015

line x loc=0.8 spacing=0.15

line y loc=0.0 spacing=0.01

line y loc=0.1 spacing=0.01

line y loc=0.4 spacing=0.02

line y loc=0.5 spacing=0.06

line y loc=1.0 spacing=0.15

#襯底摻雜硼，濃度為2e16

init c.boron=2e16

# 基區(qū)注入磷離子

implant phos energy=100 dose=8e13

# 基區(qū)退火

diffuse time=5 temp=900

# 淀積多晶硅柵厚度為0.3，設(shè)置10個(gè)網(wǎng)格

deposit poly thick=0.3 divisions=6 min.space=0.05

# 多晶摻雜 雜質(zhì)為bf2 使用劑量為3e15 能量35kev

implant bf2 dose=3e15 energy=35

# 從x=0.2um到右邊的多晶硅被刻蝕

etch poly right p1.x=0.2

# 放寬網(wǎng)格

relax y.min=.5

relax x.min=0.4

# 發(fā)射區(qū)退火

method compress fermi

diffuse time=45 temp=900 nitrogen

# 發(fā)射區(qū)離子注入

implant phos dose=2e14 energy=70

# 沉積氧化層

deposit oxide thick=0.3 divisions=10 min.space=0.1

# 刻蝕氧化層

etch oxide dry thick=0.3

# N型離子重?fù)诫s后進(jìn)行接觸區(qū)退火

implant arsenic dose=1e15 energy=50

diffuse time=30 temp=900 nitrogen

# 在接觸區(qū)淀積鋁之后反刻鋁

deposit alum thick=0.05 div=2

etch alum start x=0.16 y=-4

etch continue x=0.16 y=0.2

etch continue x=0.6 y=0.2

etch done x=0.6 y=-4

# 命名電極

electrode x=0.0 name=emitter

electrode x=0.7 name=base

electrode backside name=collector

# 提取結(jié)深

extract name="EB_xj" xj material="Silicon" mat.occno=1 x.val=0.1 junc.occno=1

extract name="BC_xj" xj material="Silicon" mat.occno=1 x.val=0.1 junc.occno=2

extract name="base_width" $BC_xj - $EB_xj

#提取一維電氣參數(shù)

extract name="base_rho" n.sheet.res material="Silicon" mat.occno=1 x.val=0.1 region.occno=2 extract name="poly_emitter_rho" p.sheet.res material="Polysilicon" mat.occno=1 x.val=0.1 region.occno=1 semi.poly

#保存最終結(jié)構(gòu)在LiTianhao-PNPBJT.str中

structure outfile=LiTianhao-PNPBJT.str

tonyplot LiTianhao-PNPBJT.str

#接下來(lái)進(jìn)行器件特性模擬

#Gummel Plot 測(cè)試

go atlas

# 設(shè)置材料和模型參數(shù)

material material=Polysilicon taun0=1e-9 taup0=1e-9 mun=40 mup=2

material material=Silicon taun0=5e-6 taup0=5e-6

models

models material=Silicon bipolar print

models material=Polysilicon srh

#提供零偏壓下勢(shì)能和載流子濃度初始值

solve init

method newton autonr trap

solve prev

#設(shè)置集電極電壓，基極電壓從-0.1到-0.4變化，-0.1步進(jìn)

solve vcollector=-2

solve vbase=-0.1 vstep=-0.1 vfinal=-0.4 name=base

log outf=LiTianhao-PNPBJT_0.log

solve vbase=-0.4 vstep=-0.05 vfinal=-1.0 name=base ac freq=1e6 aname=base

# 提取各種參數(shù)

extract name="peak collector current" max(abs(i."collector"))

extract name="peak gain" max(i."collector"/ i."base")

extract name="max fT" max(g."collector""base"/(2*3.1415*c."base""base"))

tonyplot LiTianhao-PNPBJT_0.log

# IC/VCE （輸出特性曲線）測(cè)試

go atlas

material material=Polysilicon taun0=1e-9 taup0=1e-9 mun=40 mup=2

material material=Silicon taun0=5e-6 taup0=5e-6

models

models material=Silicon bipolar print

models material=Polysilicon srh

solve init

solve vbase=-0.025

solve vbase=-0.05

solve vbase=-0.1 vstep=-0.1 vfinal=-0.7 name=base

# 設(shè)置邊界條件

contact name=base current

# 保存基極偏置電流的恒定初始值

solve ibase=-1.e-6 outf=LiTianhao-PNPBJT_1.str master

solve ibase=-2.e-6 outf=LiTianhao-PNPBJT_2.str master

solve ibase=-3.e-6 outf=LiTianhao-PNPBJT_3.str master

solve ibase=-4.e-6 outf=LiTianhao-PNPBJT_4.str master

solve ibase=-5.e-6 outf=LiTianhao-PNPBJT_5.str master

# 加載到每個(gè)初始基極電流文件和步進(jìn) VCE

load inf=LiTianhao-PNPBJT_1.str master

log outf=LiTianhao-PNPBJT_1.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

load inf=LiTianhao-PNPBJT_2.str master

log outf=LiTianhao-PNPBJT_2.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

load inf=LiTianhao-PNPBJT_3.str master

log outf=LiTianhao-PNPBJT_3.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

load inf=LiTianhao-PNPBJT_4.str master

log outf=LiTianhao-PNPBJT_4.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

load inf=LiTianhao-PNPBJT_5.str master

log outf=LiTianhao-PNPBJT_5.log

solve vcollector=0.0 vstep=-0.25 vfinal=-5.0 name=collector

# 提取峰值電流和β值

extract name="pnp_max_ic_mA" max(abs(i."collector"))*1.0e+3

extract name="pnp_lin_slope" slope(maxslope(curve(v."collector",i."collector")))

extract name="pnp_sat_slope" slope(minslope(curve(v."collector",i."collector")))

tonyplot -overlay LiTianhao-PNPBJT_5.log LiTianhao-PNPBJT_4.log LiTianhao-PNPBJT_3.log LiTianhao-PNPBJT_2.log LiTianhao-PNPBJT_1.log

quit

選做題目二：使用SILVACO軟件設(shè)計(jì)一個(gè)NPN管，進(jìn)行相應(yīng)的工藝模擬與器件模擬，要求輸出Gummel曲線及IC——VCE特性曲線，并調(diào)整相關(guān)參數(shù)，觀察并分析各關(guān)鍵工藝步驟對(duì)晶體管性能的影響。

一、用工藝軟件ATHENA制作的NPN基本結(jié)構(gòu)：

二、NPN型三極管Gummel曲線：

三、NPN型三極管共射極輸出特性曲線：

四、特性分析：

由圖可知，當(dāng)Ib改變時(shí)，Ic和Vce的關(guān)系是一組平行的曲線族，并有截止、放大、飽和三個(gè)工作區(qū)。

1、截止區(qū)：此時(shí)晶體管的集電結(jié)處于反偏，發(fā)射結(jié)電壓Vbe＜0處于反偏，由于Ib＝0，在反向飽和電流可忽略的前提下，Ic=βIb也等于0，晶體管無(wú)電流的放大作用。

2、放大區(qū)：工作在放大區(qū)的三極管有電流的放大作用，此時(shí)三極管的發(fā)射結(jié)正偏，集電結(jié)反偏，由輸出特性曲線可見，當(dāng)Ib等量變化時(shí)，Ic幾乎也按一定比例等距離平行變化，此時(shí)三極管可近似看做一個(gè)輸出電流Ic受Ib控制的受控電流源。

3、飽和區(qū)：當(dāng)集電極電流Ic增大時(shí)，Vce=Vcc-Rc將下降，對(duì)于硅管，當(dāng)Vce 降低到小于0.7V時(shí)，集電結(jié)進(jìn)入正向偏置的狀態(tài)，集電極吸引電子的能力將下降，此時(shí)即使Ib再增大，Ic也幾乎不再增大了，三極管失去了電流放大作用。這種狀態(tài)下，三極管為飽和狀態(tài)。

通過(guò)上述兩個(gè)選做題的實(shí)踐與分析可看出，NPN型三極管的輸出特性曲線和PNP型三極管的輸出特性曲線是一組關(guān)于原點(diǎn)對(duì)稱的圖象。它們電壓、電流方向不同，而且PNP三極管導(dǎo)通電壓數(shù)值較小，利用這些特點(diǎn)可以實(shí)現(xiàn)特殊要求的電路。

五、工藝對(duì)器件性能及指標(biāo)的影響分析：

（1）改變摻雜類型對(duì)NPN雙極型晶體管特性的影響：參考標(biāo)準(zhǔn)：NPN雙極型晶體管使用歐姆區(qū)摻雜，摻雜時(shí)使用高斯分布，在此基礎(chǔ)上完成后續(xù)工藝后，整個(gè)NPN雙極型晶體管的雜質(zhì)濃度分布情況如下：

參照組Gummel曲線結(jié)果如下：

參照組共射極輸出特性結(jié)果如下：

接下來(lái)建立將發(fā)射區(qū)（N型）高斯摻雜的結(jié)深擴(kuò)大十倍的對(duì)照組：用控制變量法分析將發(fā)射區(qū)（N型）高斯摻雜的結(jié)深擴(kuò)大十倍，即：doping reg=1 gauss n.type conc=5e19 peak=0.0 junct=0.5（參照組為0.05） x.right=0.8，其雜質(zhì)濃度分布情況的變化結(jié)果如下：

上述將發(fā)射區(qū)摻雜結(jié)深擴(kuò)大十倍的NPN雙極型晶體管Gummel曲線結(jié)果如下：

共射極輸出特性結(jié)果如下：

由結(jié)果可見，對(duì)于NPN型雙極型晶體管，為了獲得盡可能大的放大倍數(shù)，發(fā)射區(qū)濃度需要很大，以便可以發(fā)射足夠多的載流子。而通過(guò)上述對(duì)照組可知，將發(fā)射區(qū)高斯摻雜的結(jié)深擴(kuò)大，會(huì)使其發(fā)射區(qū)摻雜濃度變大，進(jìn)而使得放大區(qū)輸出特性曲線斜率變大，意味著NPN管的放大倍數(shù)變大。因此，需要提高NPN晶體管的放大倍數(shù)時(shí)，可以通過(guò)增大其發(fā)射區(qū)結(jié)深與摻雜濃度實(shí)現(xiàn)。

六、附錄：實(shí)驗(yàn)程序與詳細(xì)注釋：

go atlas

# 建立網(wǎng)格

mesh

x.m l=0 spacing=0.15

x.m l=0.8 spacing=0.15

x.m l=1.0 spacing=0.03

x.m l=1.5 spacing=0.12

x.m l=2.0 spacing=0.15

y.m l=0.0 spacing=0.006

y.m l=0.04 spacing=0.006

y.m l=0.06 spacing=0.005

y.m l=0.15 spacing=0.02

y.m l=0.30 spacing=0.02

y.m l=1.0 spacing=0.12

#定義發(fā)射區(qū)，集電區(qū)，基區(qū)三個(gè)區(qū)域，同時(shí)分析代碼：歐姆區(qū)摻雜（因?yàn)殡姌O還要做重?fù)诫s才可以做成歐姆接觸，所以做歐姆接觸需要摻雜）

region num=1 silicon

electrode num=1 name=emitter left length=0.8

electrode num=2 name=base right length=0.5 y.max=0

electrode num=3 name=collector bottom

#摻雜：高斯分布（離子注入時(shí)均勻摻雜突變結(jié)，實(shí)際情況是緩變結(jié)。）

doping reg=1 uniform n.type conc=5e15

doping reg=1 gauss n.type conc=1e18 peak=1.0 char=0.2

doping reg=1 gauss p.type conc=1e18 peak=0.05 junct=0.15

doping reg=1 gauss n.type conc=5e19 peak=0.0 junct=0.05 x.right=0.8

doping reg=1 gauss p.type conc=5e19 peak=0.0 char=0.08 x.left=1.5

#工藝仿真器件制作完成，保存到我的LiTianhao-BJT_athena.str文件中

save outf=LiTianhao-BJT_athena.str

tonyplot LiTianhao-BJT_athena.str

#接下來(lái)進(jìn)行器件特性仿真：

models conmob fldmob consrh auger print

contact name=emitter n.poly surf.rec

# Gummel plot仿真

solve init

method newton autonr trap

solve vcollector=0.025

solve vcollector=0.1

solve vcollector=0.25 vstep=0.25 vfinal=2 name=collector

solve vbase=0.025

solve vbase=0.1

solve vbase=0.2

log outf= LiTianhao-BJT_0.log

solve vbase=0.3 vstep=0.05 vfinal=1 name=base

tonyplot LiTianhao-BJT_0.log

#IC/VCE仿真，此時(shí)基極電流恒定

#偏置基極

log off

solve init

solve vbase=0.025

solve vbase=0.05

solve vbase=0.1 vstep=0.1 vfinal=0.7 name=base

#定義基極為電流邊界

contact name=base current

#將基極偏置到不同的電流值

solve ibase=1.e-6

save outf=LiTianhao-BJT_1.str master

solve ibase=2.e-6

save outf=LiTianhao-BJT_2.str master

solve ibase=3.e-6

save outf=LiTianhao-BJT_3.str master

solve ibase=4.e-6

save outf=LiTianhao-BJT_4.str master

solve ibase=5.e-6

save outf=LiTianhao-BJT_5.str master

#載入不同基極電流,偏置集電極

load inf=LiTianhao-BJT_1.str master

log outf=LiTianhao-BJT_1.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector

load inf=LiTianhao-BJT_2.str master

log outf=LiTianhao-BJT_2.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector

load inf=LiTianhao-BJT_3.str master

log outf=LiTianhao-BJT_3.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector

load inf=LiTianhao-BJT_4.str master

log outf=LiTianhao-BJT_4.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector

load inf=LiTianhao-BJT_5.str master

log outf=LiTianhao-BJT_5.log

solve vcollector=0.0 vstep=0.25 vfinal=5.0 name=collector

#輸出曲線族

tonyplot -overlay LiTianhao-BJT_1.log LiTianhao-BJT_2.log LiTianhao-BJT_3.log LiTianhao-BJT_4.log LiTianhao-BJT_5.log

quit