@echo off

Color a9

rem rarPath:WINRAR安裝路徑

set rarPath="E:\Program Files\WinRAR\WinRAR.exe"

echo WINRAR安裝路徑是：%rarPath%

rem currentDate:獲取的當(dāng)前日期字符串

for /f "tokens=1,2,3 delims=/- " %%a in ("%date%") do @set currentDateNow=%%a%%b%%c

echo 獲取的當(dāng)前日期字符串是：%currentDateNow%

@echo off

rem 計(jì)算指定天數(shù)之前的日期

set DaysAgo=2

rem 假設(shè)系統(tǒng)日期的格式為yyyymmdd

call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays

set /a PassDays-=%DaysAgo%

call :DaysToDate %PassDays% DstYear DstMonth DstDay

set currentDate=%DstYear%%DstMonth%%DstDay%

echo 獲取的%DaysAgo%天的日期是%currentDate%

rem workPath:工作路徑

set workPath="D:\WorkOrderEngine\WorkOrderEngine\csv"

echo 工作路徑是：%workPath%

rem bakPath:備份文件夾

set bakPath="D:\WorkOrderEngine\WorkOrderEngine\csv\%currentDate%"

echo 備份文件夾是：%bakPath%

echo 開始生成備份文件夾

md %bakPath%

echo 開始復(fù)制文件到備份文件夾

if exist %workPath%\*%currentDate%*.csv copy %workPath%\*%currentDate%*.csv %bakPath%\

echo 開始備份

%rarPath% a -ibck -m5 %bakPath%.rar %bakPath%

echo 備份完成

Pause

:DateToDays %yy% %mm% %dd% days

setlocal ENABLEEXTENSIONS

set yy=%1&set mm=%2&set dd=%3

if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)

set /a dd=100%dd%%%100,mm=100%mm%%%100

set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2

set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633

endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd

setlocal ENABLEEXTENSIONS

set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a

set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5

set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10

(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)

endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF