Vlookup的升級版Xlookup函數(shù)已經(jīng)跟大家介紹過了，今天跟大家分享下Index+Match的升級版，主要就是Match函數(shù)的升級，作用與Xlookup相似，但是XMatch卻更加的靈活一些，有需要的粉絲可以看下~

一、了解XMATCH

Xmatch：查找數(shù)據(jù)在表格區(qū)域的項目位置

語法：=XMATCH (lookup_value、lookup_array、[match_mode]、[search_mode])

第一參數(shù)：查找值

第二參數(shù)：查找的數(shù)據(jù)區(qū)域

第二參數(shù)：匹配類型，它是一個可選參數(shù)，一共有四個匹配類型

0： 精確匹配（默認(rèn)，省略第三參數(shù)則默認(rèn)設(shè)置為0） -1： 完全匹配或下一個最小項 1： 完全匹配獲下一個最大項 2：通配符匹配

第四參數(shù)：搜索類型，它也是一個可選參數(shù)，有四個搜索類型

1 ： 正序搜索， （默認(rèn)，省略第三參數(shù)則默認(rèn)設(shè)置為1） -1 ： 搜索倒序搜索 。 2 ：依賴于lookup_array按升序排序的二進(jìn)制搜索 -2 ：依賴于 lookup_array 按降序排序的二進(jìn)制搜索

如下圖，我們想要在表格中查找【張飛】在姓名的位置，就可以使用XMATCH函數(shù)

公式：=XMATCH(F3,A2:A9,0)

結(jié)果為3，就表示張飛在姓名這一列的第三個位置

XMATCH函數(shù)的作用就是查找數(shù)據(jù)的位置，它需要搭配INDEX函數(shù)才能實(shí)現(xiàn)數(shù)據(jù)查詢，下面我們就來了解下都有哪些操作吧！

一、常規(guī)查找

在這里我們想要查找【武則天的數(shù)學(xué)成績】，公式為

=INDEX(D1:D9,XMATCH(G4,A1:A9,0))

二、多條件查找

有2個或者2個以上的查找，我就稱之為多條件查詢，一般都是為了解決查找值重復(fù)的問題

如下圖，魯班有重名，而現(xiàn)實(shí)我們需要查找【2班魯班】的數(shù)據(jù)成績，公式為

=INDEX(E1:E9,XMATCH(G3&H3,A1:A9&B1:B9,0))

操作與常規(guī)查找類似，只需使用連接符號在Xmatch中將班級與姓名連接在一起即可

三、反向查找

反向查找是Vlookup的專屬名詞，因?yàn)閂lookup找不到查找值左側(cè)的數(shù)據(jù)，如果想要找到查找值左側(cè)的數(shù)據(jù)，我就稱之為反向查詢，但是對于INDEX+XMTACH是不存在反向查詢這一說的，它們左右都是可以查詢的，就是函數(shù)的常規(guī)用法

如下圖，我們根據(jù)學(xué)號，可以使用函數(shù)輕松的查找姓名

=INDEX(A1:A9,XMATCH(G4,B1:B9,0))

四、關(guān)鍵字查詢

所謂的關(guān)鍵字查詢，就是我們可以通過輸入關(guān)鍵字來查找數(shù)據(jù)，不過需要借助通配符，常用的有2個

?：表示任意單個字符

*：表示任意多個字符

其實(shí)就是INDEX+XMTACH，我們在查找值中設(shè)置通配符來取代實(shí)際的數(shù)字即可，在這里我們是直接輸入在單元格的，使用連接符號連接也是可以的

=INDEX(D1:D9,XMATCH(G2,A1:A9,2))

五、查找多列數(shù)據(jù)

我們可以使用設(shè)置一次公式，快速查找多行多列的數(shù)據(jù)，在這里我們需要使用2個Xmatch函數(shù)來確定數(shù)據(jù)的行列標(biāo)號，跟常用用法相似，只不新增一個Xmatch函數(shù)用于確定行標(biāo)號

=INDEX($A$1:$G$10,XMATCH($I2,$A$1:$A$10,0),XMATCH(J$1,$A$1:$G$1,0))即可

六、區(qū)間查找

INDEX+XMATCH也可以進(jìn)行區(qū)間查找，操作與Xlookup函數(shù)類似，也需要先構(gòu)建一個數(shù)據(jù)區(qū)域，取區(qū)間的最小值來對應(yīng)等級，下圖橙色區(qū)域就是我們構(gòu)建的區(qū)域

=INDEX($F$8:$F$11,XMATCH(B2,$E$8:$E$11,-1))

主要是利用XMATCH的第三參數(shù)，如果函數(shù)找不到精確的結(jié)果，就會返回小于查找值的最大值，原理與Vlookup函數(shù)的近似匹配一致

六、查找最后出現(xiàn)的數(shù)據(jù)

在這里我們利用的XMATCH的倒序查詢，一般函數(shù)都是從下到下進(jìn)行數(shù)據(jù)查詢的，但是XMATCH卻可以從下往上查詢

如下圖，我們需要在操作時間中找到魯班最后一次操作時間

=INDEX(B1:B25,XMATCH(D2,A1:A25,0,-1))

關(guān)鍵就是將XMATCH的第四參數(shù)設(shè)置為了-1，讓XMATCH從下往上進(jìn)行數(shù)據(jù)查詢，因?yàn)檫@個時間是從小到大排列的。

以上就是今天分享的7個關(guān)于INDEX+XMATCH函數(shù)的常見用法，他們的作用遠(yuǎn)不止于此，以后會跟大家分享他們更多的使用技巧